Hàm RIGHT, cách dùng hàm cắt chuỗi ký tự bên phải trong Excel

Để tìm kiếm thông tin, dữ liệu trên bảng Excel chúng ta có thể sử dụng nhiều hàm khác nhưu như hàm VLOOKUP trên Excel, hàm LEFT tách chuỗi ký tự Excel,.. Và trong bài viết này người dùng sẽ biết thêm cách dùng hàm RIGHT để tìm ký tự trong một chuỗi ký tự lựa chọn.

Nếu hàm LEFT để tách chuỗi ký tự bên trài thì hàm RIGHT ngược lại, tách chuỗi ký tự từ bên phải trong một dãy ký tự mà người dùng lựa chọn. Khi đó hàm RIGHT trả về kết quả là một hoặc nhiều ký tự cuối trong một chuỗi văn bản dựa vào số lượng ký tự hiển thị trong trong ô dữa liệu. Bài viết dưới đây sẽ hướng dẫn bạn đọc cách sử dụng hàm RIGHT trên Excel.

• Cách kết hợp hàm Sumif và hàm Vlookup trên Excel
• Dùng hàm VLOOKUP để nối gộp hai bảng Excel với nhau
• Cách sử dụng hàm MID lấy chuỗi ký tự trong Excel
• Hướng dẫn cách sửa lỗi ngày tháng đảo ngược trong Excel

Hướng dẫn dùng hàm RIGHT trên Excel

Hàm RIGHT có cú pháp sử dụng là =RIGHT(text,[num_chars]). Trong đó:

• text: là chuỗi văn bản các bạn muốn trích xuất các ký tự.
• num_chars: số lượng ký tự mà các bạn muốn hàm RIGHT() trích xuất.

Lưu ý:

• Nếu num_chars bỏ qua thì mặc định của nó là 1.
• Num_chars luôn phải lớn hơn hoặc bằng 0.
• Nếu num_chars lớn hơn độ dài của chuỗi văn bản thì hàm RIGHT trả về toàn bộ chuỗi văn bản.

Ví dụ 1: Dùng hàm RIGHT tìm ký tự

Chẳng hạn với bảng dữ liệu dưới đây, tiến hành trích xuất 3 ký tự cuối trong từng ô dữ liệu. Tại ô kết quả nhập công thức =RIGHT(B2,3) rồi nhấn Enter.

Kết quả chúng ta được 3 ký tự cuối cùng trong dãy ký tự như hình dưới đây. Kéo xuống những ô còn lại để hiện các kết quả khác.

Ngoài ra chúng ta cũng có thể nhập trực tiếp dãy ký tự như hình dưới đây nhưng phải dùng dấu ngoặc kép.

Ví dụ 2: Hàm RIGHT kết hợp hàm VALUE

2 hàm này kết hợp với nhau sẽ trả về kết quả là giá trị số. Do hàm RIGHT trong Excel luôn trả về chuỗi văn bản, ngay cả khi giá trị gốc là chữ số. Nếu dùng thêm hàm VALUE thì kết quả là số. Bạn tham khảo ví dụ kết hợp 2 hàm trong bài viết Cách sử dụng hàm VALUE trong Excel.

Ví dụ 3: Hàm RIGHT xuất ký tự sau 1 ký tự cụ thể

Khi muốn tách chuỗi ký tự theo sau một ký tự cụ thể cần dùng hàm SEARCH trong Excel hoặc hàm FIND để xác định vị trí ký tự đó, nhưng trừ vị trí ký tự được chọn trong tổng chuỗi ký tự được trả về bằng hàm LEN. Công thức kết hợp là =RIGHT(chuỗi văn bản, LEN(chuỗi văn bản) - SEARCH(kí tự, chuỗi van bản)).

Với bảng ví dụ này cần tìm phần tên trong ô Họ tên, nhập công thức =RIGHT(B2,LEN(B2)-SEARCH(" ",B2)) và nhấn Enter.

Kết quả chúng ta được tên như hình dưới đây. Kéo xuống bên dưới để hiển thị những kết quả còn lại.

Với việc kết hợp 3 hàm trên, chúng ta có thể áp dụng để xuất chuỗi theo sau bất kỳ một ký tự khác, như dấu phẩy, hai chấm, dấu gạch nối,...

Ví dụ 4: Hàm RIGHT loại n ký tự đầu tiên trong chuỗi

Công thức sử dụng RIGHT(string, LEN(string)-number_of_chars_to_remove).

Trong bảng dữ liệu này sẽ loại bỏ 6 ký tự đầu tiên bao gồm dấu chấm khỏi chuỗi ký tự. Nhập công thức =RIGHT(B2, LEN(B2)-6) rồi nhấn Enter. Kết quả chúng ta được kết quả như hình dưới đây.

Ví dụ 5: Hàm RIGHT xuất ký tự sau dấu phân cách cuối cùng

Với những chuỗi phức tạp nhiều dấu phân cách, thì việc trích xuất nội dung phải tách từ dấu phân cách cuối cùng. Với bảng dữ liệu dưới đây có ô chỉ dùng 1 dấu phân cách, nhưng có ô dùng tới 2 dấu phân cách và yêu cầu sẽ lấy ký tự sau dấu phân cách cuối cùng.

Áp công thức vào bảng dữ liệu này chúng ta nhập =RIGHT(B6,LEN(B6)-SEARCH("$",SUBSTITUTE(B6,":","$",LEN(B6)-LEN(SUBSTITUTE(B6,":",""))))) và nhấn Enter. Trong đó

• LEN(B6): tổng chiều dài của chuỗi ký tự trong ô B6.
• LEN(SUBSTITUTE(B6,":","")): chiều dài của chuỗi ký tự không có dấu hai chấm.
• LEN(B6)-LEN(SUBSTITUTE(B6,":","")): tổng chiều dài ban đầu trừ đi chiều dài chuỗi ký tự không có dấu hai chấm.
• SUBSTITUTE(B6,":","$",LEN(B6)-LEN(SUBSTITUTE(B6,":",""))): thay thế dấu hai chấm phân tách cuối cùng bằng ký tự mới $, hàm SUBSTITUTE cho phép thay thế ký tự được chỉ định trong chuỗi.
• SEARCH("$",SUBSTITUTE(B6,":","$",LEN(B6)-LEN(SUBSTITUTE(B6,":","")))): xác định vị trí của dấy phân tách cuối cùng, trong hình dấu hai chấm được thay bằng dấu $.
• RIGHT(B6,LEN(B6)-SEARCH("$",SUBSTITUTE(B6,":","$",LEN(B6)-LEN(SUBSTITUTE(B6,":",""))))): trả về chuỗi bên phải dấu phân tách cuối cùng, lấy tổng chiều dài chuỗi trừ đi vị trí của dấu phân cách.

Kết quả chúng được dãy ký tự như hình dưới đây.

Chúc các bạn thực hiện thành công!